3 files changed, 113 insertions, 0 deletions
diff --git a/recipes-devtools/mraa/mraa.inc b/recipes-devtools/mraa/mraa.inc
new file mode 100644
index 0000000..52476c4
--- /dev/null
+++ b/recipes-devtools/mraa/mraa.inc
@@ -0,0 +1,57 @@
+SUMMARY = "Low Level Skeleton Library for Communication on Intel platforms"
+SECTION = "libs"
+AUTHOR = "Brendan Le Foll, Tom Ingleby"
+
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://COPYING;md5=66493d54e65bfc12c7983ff2e884f37f"
+
+S = "${WORKDIR}/git"
+
+inherit distutils-base pkgconfig python-dir cmake
+
+DEPENDS = "python3 git nodejs python3-native git-native nodejs-native"
+
+PACKAGES =+ "python-${PN} node-${PN}"
+
+# python-mraa package containing Python bindings
+FILES_python-${PN} = "${PYTHON_SITEPACKAGES_DIR}/ \
+                      ${datadir}/mraa/examples/python/ \
+                      ${prefix}/src/debug/${BPN}/${PV}-${PR}/build/src/python/ \
+                     "
+RDEPENDS_python-${PN} += "python"
+INSANE_SKIP_python-${PN} = "debug-files"
+
+# node-mraa package containing Nodejs bindings
+FILES_node-${PN} = "${libdir}/node_modules/ \
+                    ${datadir}/mraa/examples/javascript/ \
+                   "
+RDEPENDS_node-${PN} += "nodejs"
+INSANE_SKIP_node-${PN} = "debug-files"
+
+FILES_${PN}-doc += "${datadir}/mraa/examples/"
+
+PACKAGECONFIG ??= "python nodejs"
+PACKAGECONFIG[python] = "-DBUILDSWIGPYTHON=ON, -DBUILDSWIGPYTHON=OFF, swig-native python,"
+PACKAGECONFIG[nodejs] = "-DBUILDSWIGNODE=ON, -DBUILDSWIGNODE=OFF, swig-native nodejs,"
+PACKAGECONFIG[java] = "-DBUILDSWIGJAVA=ON, -DBUILDSWIGJAVA=OFF, swig-native icedtea7-native,"
+
+EXTRA_OECMAKE_append = "-DINSTALLGPIOTOOL=ON -DPYTHON_SITE_DIR:FILEPATH=${PYTHON_SITEPACKAGES_DIR} -DBASE_LIB_INSTALL_DIR=${base_libdir} -DCMAKE_SKIP_RPATH=ON"
+
+export JAVA_HOME="${STAGING_DIR}/${BUILD_SYS}/usr/lib/jvm/icedtea7-native"
+
+cmake_do_generate_toolchain_file_append() {
+  echo "
+set (JAVA_AWT_INCLUDE_PATH ${JAVA_HOME}/include CACHE PATH \"AWT include path\" FORCE)
+set (JAVA_AWT_LIBRARY ${JAVA_HOME}/jre/lib/amd64/libjawt.so CACHE FILEPATH \"AWT Library\" FORCE)
+set (JAVA_INCLUDE_PATH ${JAVA_HOME}/include CACHE PATH \"java include path\" FORCE)
+set (JAVA_INCLUDE_PATH2 ${JAVA_HOME}/include/linux CACHE PATH \"java include path\" FORCE)
+set (JAVA_JVM_LIBRARY ${JAVA_HOME}/jre/lib/amd64/libjvm.so CACHE FILEPATH \"path to JVM\" FORCE)
+" >> ${WORKDIR}/toolchain.cmake
+}
+
+do_compile_prepend () {
+  # when yocto builds in ${D} it does not have access to ../git/.git so git
+  # describe --tags fails. In order not to tag our version as dirty we use this
+  # trick
+  sed -i 's/-dirty//' src/version.c
+}
diff --git a/recipes-devtools/mraa/mraa_1.5.1.bb b/recipes-devtools/mraa/mraa_1.5.1.bb
new file mode 100644
index 0000000..d2bd44b
--- /dev/null
+++ b/recipes-devtools/mraa/mraa_1.5.1.bb
@@ -0,0 +1,12 @@
+require mraa.inc
+
+SRCREV = "6f9b470d8d25e2c8ba1586cd9d707b870ab30010"
+SRCREV_de10-nano = "81457f02c3b1bbccfc0a88be1af23335c9457da4"
+SRCREV_de0-nano = "81457f02c3b1bbccfc0a88be1af23335c9457da4"
+
+SRC_URI = "git://github.com/intel-iot-devkit/mraa.git;protocol=https"
+SRC_URI_de10-nano = "git://github.com/Propanu/mraa.git;protocol=https;branch=de10-nano"
+SRC_URI_de0-nano = "git://github.com/Propanu/mraa.git;protocol=https;branch=de10-nano"
+
+PACKAGECONFIG_de10-nano ?= "python nodejs"
+PACKAGECONFIG_de0-nano ?= "python nodejs"
diff --git a/recipes-devtools/upm/upm_1.1.0.bb b/recipes-devtools/upm/upm_1.1.0.bb
new file mode 100644
index 0000000..b945df1
--- /dev/null
+++ b/recipes-devtools/upm/upm_1.1.0.bb
@@ -0,0 +1,44 @@
+SUMMARY = "Sensor/Actuator repository for Mraa"
+SECTION = "libs"
+AUTHOR = "Brendan Le Foll, Tom Ingleby, Yevgeniy Kiveisha"
+
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=66493d54e65bfc12c7983ff2e884f37f"
+
+DEPENDS = "nodejs mraa"
+
+SRCREV="b9988469ba5d353456d5a162ae807caa0475dbab"
+
+SRC_URI = "git://github.com/intel-iot-devkit/upm.git \
+          "
+
+S = "${WORKDIR}/git"
+
+inherit distutils-base pkgconfig python-dir cmake
+
+PACKAGES =+ "python-${PN} node-${PN}"
+
+# python-upm package containing Python bindings
+FILES_python-${PN} = "${PYTHON_SITEPACKAGES_DIR}/ \
+                      ${datadir}/${BPN}/examples/python/ \
+                      ${prefix}/src/debug/${BPN}/${PV}-${PR}/build/src/*/pyupm_* \
+                     "
+RDEPENDS_python-${PN} += "python mraa"
+INSANE_SKIP_python-${PN} = "debug-files"
+
+
+# node-upm package containing Nodejs bindings
+FILES_node-${PN} = "${libdir}/node_modules/ \
+                    ${datadir}/${BPN}/examples/javascript/ \
+                   "
+RDEPENDS_node-${PN} += "nodejs mraa"
+INSANE_SKIP_node-${PN} = "debug-files"
+
+FILES_${PN}-doc += " ${datadir}/upm/examples/"
+RDEPENDS_${PN} += " mraa"
+
+PACKAGECONFIG ??= "python nodejs"
+PACKAGECONFIG[python] = "-DBUILDSWIGPYTHON=ON, -DBUILDSWIGPYTHON=OFF, swig-native python python3,"
+PACKAGECONFIG[nodejs] = "-DBUILDSWIGNODE=ON, -DBUILDSWIGNODE=OFF, swig-native nodejs,"
+PACKAGECONFIG[java] = "-DBUILDSWIGJAVA=ON, -DBUILDSWIGJAVA=OFF, swig-native icedtea7-native,"
+