From 9a293641b9abf9e4fca34f46a2de781f50847da9 Mon Sep 17 00:00:00 2001
From: "Westergreen, Dalon" <dalon.westergreen@intel.com>
Date: Wed, 29 Mar 2017 15:41:36 -0700
Subject: Initial commit of de10-nano recipes
Please note that this is purely for development. Only superficial
efforts have been made to resolve security concerns, and it should
be noted that the board ships with an EMPTY ROOT PASSWORD and support
for root login via ssh. This allows passwordless access to the board
via ssh.
recipes-bsp/u-boot:
Contains the uboot 2017.03rc2 recipe and patches to support the
de10-nano board
recipes-connectivity/avahi:
bbappend to remove unwanted packages
recipes-connectivity/bluez:
bbappend to add --compat to the bluetooth service to support legacy
SDP APIs
recipes-connectivity/openssh:
bbappend to add a custom sshd_config
recipes-core/base-files:
bbappend to customize fstab and inputrc
recipes-core/imagemagick:
bbappend to change build configuration for the de10-nano board
recipes-core/packagegroups:
bbappend to remove an unwanted package
recipes-core/webkit:
bbappend to remove support for opengl
recipes-demo:
Various demo applications
recipes-devtools:
MRAA and UPM recipes
recipes-images/angstrom/de10-nano-image.bb:
DE10-Nano image definition
recipes-kernel/de10-nano-linux-firmware:
FPGA related firmware required for fpga configuration and devicetree
overlay support
recipes-kernel/linux:
bbappend to customize configuration of linux kernel as well as patch
in the de10-nano devicetree
recipes-misc:
various initialization and systemd scripts
recipes-qt/qt5:
bbappend to modify qt build options
recipes-support/neon:
bbappend to remove unwanted package
recipes-support/upower:
bbappend to remove unwanted package
recipes-webserver:
webserver configuration and webcontent for board hostedweb portal
recipes-xfce/thunar-volman:
bbappend to remove unwanted package
recipes-xfce/xfce-pointers:
add configuration so that xfce does not use the adxl input as a mouse
recipes-xfce/xfce4-settings:
bbappend to remove unwanted package
Signed-off-by: Westergreen, Dalon <dalon.westergreen@intel.com>
---
recipes-devtools/mraa/mraa.inc | 57 +++++++++++++++++++++++++++++++++++++
recipes-devtools/mraa/mraa_1.5.1.bb | 12 ++++++++
2 files changed, 69 insertions(+)
create mode 100644 recipes-devtools/mraa/mraa.inc
create mode 100644 recipes-devtools/mraa/mraa_1.5.1.bb
(limited to 'recipes-devtools/mraa')
diff --git a/recipes-devtools/mraa/mraa.inc b/recipes-devtools/mraa/mraa.inc
new file mode 100644
index 0000000..52476c4
--- /dev/null
+++ b/recipes-devtools/mraa/mraa.inc
@@ -0,0 +1,57 @@
+SUMMARY = "Low Level Skeleton Library for Communication on Intel platforms"
+SECTION = "libs"
+AUTHOR = "Brendan Le Foll, Tom Ingleby"
+
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://COPYING;md5=66493d54e65bfc12c7983ff2e884f37f"
+
+S = "${WORKDIR}/git"
+
+inherit distutils-base pkgconfig python-dir cmake
+
+DEPENDS = "python3 git nodejs python3-native git-native nodejs-native"
+
+PACKAGES =+ "python-${PN} node-${PN}"
+
+# python-mraa package containing Python bindings
+FILES_python-${PN} = "${PYTHON_SITEPACKAGES_DIR}/ \
+ ${datadir}/mraa/examples/python/ \
+ ${prefix}/src/debug/${BPN}/${PV}-${PR}/build/src/python/ \
+ "
+RDEPENDS_python-${PN} += "python"
+INSANE_SKIP_python-${PN} = "debug-files"
+
+# node-mraa package containing Nodejs bindings
+FILES_node-${PN} = "${libdir}/node_modules/ \
+ ${datadir}/mraa/examples/javascript/ \
+ "
+RDEPENDS_node-${PN} += "nodejs"
+INSANE_SKIP_node-${PN} = "debug-files"
+
+FILES_${PN}-doc += "${datadir}/mraa/examples/"
+
+PACKAGECONFIG ??= "python nodejs"
+PACKAGECONFIG[python] = "-DBUILDSWIGPYTHON=ON, -DBUILDSWIGPYTHON=OFF, swig-native python,"
+PACKAGECONFIG[nodejs] = "-DBUILDSWIGNODE=ON, -DBUILDSWIGNODE=OFF, swig-native nodejs,"
+PACKAGECONFIG[java] = "-DBUILDSWIGJAVA=ON, -DBUILDSWIGJAVA=OFF, swig-native icedtea7-native,"
+
+EXTRA_OECMAKE_append = "-DINSTALLGPIOTOOL=ON -DPYTHON_SITE_DIR:FILEPATH=${PYTHON_SITEPACKAGES_DIR} -DBASE_LIB_INSTALL_DIR=${base_libdir} -DCMAKE_SKIP_RPATH=ON"
+
+export JAVA_HOME="${STAGING_DIR}/${BUILD_SYS}/usr/lib/jvm/icedtea7-native"
+
+cmake_do_generate_toolchain_file_append() {
+ echo "
+set (JAVA_AWT_INCLUDE_PATH ${JAVA_HOME}/include CACHE PATH \"AWT include path\" FORCE)
+set (JAVA_AWT_LIBRARY ${JAVA_HOME}/jre/lib/amd64/libjawt.so CACHE FILEPATH \"AWT Library\" FORCE)
+set (JAVA_INCLUDE_PATH ${JAVA_HOME}/include CACHE PATH \"java include path\" FORCE)
+set (JAVA_INCLUDE_PATH2 ${JAVA_HOME}/include/linux CACHE PATH \"java include path\" FORCE)
+set (JAVA_JVM_LIBRARY ${JAVA_HOME}/jre/lib/amd64/libjvm.so CACHE FILEPATH \"path to JVM\" FORCE)
+" >> ${WORKDIR}/toolchain.cmake
+}
+
+do_compile_prepend () {
+ # when yocto builds in ${D} it does not have access to ../git/.git so git
+ # describe --tags fails. In order not to tag our version as dirty we use this
+ # trick
+ sed -i 's/-dirty//' src/version.c
+}
diff --git a/recipes-devtools/mraa/mraa_1.5.1.bb b/recipes-devtools/mraa/mraa_1.5.1.bb
new file mode 100644
index 0000000..d2bd44b
--- /dev/null
+++ b/recipes-devtools/mraa/mraa_1.5.1.bb
@@ -0,0 +1,12 @@
+require mraa.inc
+
+SRCREV = "6f9b470d8d25e2c8ba1586cd9d707b870ab30010"
+SRCREV_de10-nano = "81457f02c3b1bbccfc0a88be1af23335c9457da4"
+SRCREV_de0-nano = "81457f02c3b1bbccfc0a88be1af23335c9457da4"
+
+SRC_URI = "git://github.com/intel-iot-devkit/mraa.git;protocol=https"
+SRC_URI_de10-nano = "git://github.com/Propanu/mraa.git;protocol=https;branch=de10-nano"
+SRC_URI_de0-nano = "git://github.com/Propanu/mraa.git;protocol=https;branch=de10-nano"
+
+PACKAGECONFIG_de10-nano ?= "python nodejs"
+PACKAGECONFIG_de0-nano ?= "python nodejs"
--
cgit v1.1